【蒟蒻科技】使用vbs脚本控制键盘和鼠标

咳咳咳,又是新的一年,在这里就祝大家在新的一年万事如意,天天打程序;财源广进,IOI夺金。这一小段时间,我抽空研究了一下脚本,今天就简单的介绍一点皮毛吧(我才不会告诉你是因为难的我不会咧。:laughing:)

编程工具

俗话说:工欲善其事必先利其器,所以好的编程软件非常重要。今天我们介绍的语言是Microsoft Visual Basic Script Editio(简称vbs),它的编程软件就是非常好用的记事本。没错,就是记事本编程!我们只需要使用记事本编写好程序,再把后缀名改为vbs,双击程序就可以直接运行了,是不是很方便呢?

控制键盘

相比较与控制鼠标,控制键盘要简单的多。由于vbs相对于cpp,语法简单的多。所以程序只需大体分为两部分。

定义变量和对象

在vbs中,我们一般用Dim来定义一个变量,首先我们先定义一个叫WshShell的变量,如下:

Dim WshShell

接着我们要创建 COM 对象,具体用法为:

object.CreateObject(strProgID[,strPrefix])

其中参数的意思是:
object :WScript 对象。
strProgID :表示要创建的对象的编程标识符 (ProgID) 的字符串值。
strPrefix :可选。表示函数前缀的字符串值。

PS:

使用 strPrefix 参数,通过 CreateObject 方法创建的对象是已连接的对象。当您要同步对象的事件时,这些对象非常有用。创建对象后,该对象的输出接口将连接到脚本文件。事件函数由该前缀和事件名称组成。如果您创建对象时未提供 strPrefix 参数,则仍可通过 ConnectObject 方法同步发生在该对象上的事件。当对象引发事件时,WSH 将调用在事件名称开头附加了 strPrefix 的子例程。例如,如果 strPrefix 是 MYOBJ,对象引发的事件名为 OnBegin,则 Windows 脚本宿主将调用脚本中的 MYOBJ_OnBegin 子例程。CreateObject 方法返回一个指向该对象的 IDispatch 接口的指针。

下面我们的 VBScript 代码使用 CreateObject 方法创建 WScript.Shell 对象:

Set WshShell=WScript.CreateObject("WScript.Shell")

输出操作

在vbs中有一个很好用的指令,叫做:Sendkeys,但是由于我们是对于上文讲到的对象进行操作的,所以具体操作时应该为WshShell.sendkeys ""双引号中就是要键盘输出的东西(也可以是按键比如cirl)。

比如WshShell.sendkeys "233"就是模拟键盘输出233。

另外的,可使用 SendKeys 同时发送多个键击。为此,可将每个键击按顺序排列在一起,以此来创建表示一系列键击的复合字符串参数。例如,要发送键击 a、b 和 c,则需要发送字符串参数 "abc" 。

特别的,SendKeys 方法将某些字符用作字符的修饰符(而不使用其本身的含义)。这组特殊的字符可包括圆括号、中括号、大括号,以及:

加号 "+"
插入记号 "^"
百分号 "%"
和“非”符号 "~"
用大括号 "{}" 括起这些字符可以发送它们。

举个栗子!

要发送加号,请使用字符串参数 "{+}";
要发送左大括号字符,请发送字符串参数 "{{}";
要发送右大括号字符,请发送字符串参数 "{}}"。

某些键击不生成字符(如 ENTER 和 TAB)。某些键击表示操作(如 BACKSPACE 和 BREAK)。要发送这些类型的键击,请发送下表中列出的参数:

  空格键           " "
  退格键           {BACKSPACE} 或 {BS} 或 {BKSP}    
  BREAK           {BREAK}    
  DELETE         {DELETE}     或     {DEL}    
  向下键           {DOWN}
  向上键           {UP}
  向左键           {LEFT}
  向右键           {RIGHT}   
  END              {END}    
  ENTER           {ENTER}     或     ~    
  ESC              {ESC}
  TAB              {TAB}
  CAPS LOCK       {CAPSLOCK}              
  HELP             {HELP}    
  HOME            {HOME}    
  INSERT          {INSERT}     或     {INS}    
  NUM LOCK          {NUMLOCK}    
  PAGE DOWN       {PGDN}    
  PAGE UP            {PGUP}    
  PRINT SCREEN    {PRTSC}    
  SCROLL LOCK     {SCROLLLOCK}    
  F1       {F1}    
  F2       {F2}    
  F3       {F3}    
  F4       {F4}    
  F5       {F5}    
  F6       {F6}    
  F7       {F7}    
  F8       {F8}    
  F9       {F9}    
  F10     {F10}    
  F11     {F11}    
  F12     {F12}    

要发送由常规键击和 SHIFT、CTRL 或 ALT 组合而成的键盘字符,请创建表示该键击组合的复合字符串参数。可通过在常规键击之前添加一个或多个以下特殊字符来完成上述操作:

SHIFT +
CTRL ^
ALT %

到这里你应该已经会简单的操作了吧。那有人会问了,如果我想给女朋友发520次怎么办?嘿嘿嘿,这时我们就要用上循环语句了:

for i=1 to 520
WScript.Sleep 2000
WshShell.sendkeys "I LOVE YOU{ENTER}" 
next

只要在for 和 next 之间加入循环体就行了,非常简单。
PS.sleep x是休息的x ms的意思。发一次停2s更让人感觉真实(滑稽)。

控制鼠标

首先,使用这段代码的前提是你的系统上安装了Excel,因为要用到Excel.Application对象。

原理不是特别复杂,就是通过Excel.Application对象调用电脑的API进行操作,就不具体讲解了,具体代码如下:

Option Explicit
Dim WshShell
Dim oExcel, oBook, oModule
Dim strRegKey, strCode, x, y
Set oExcel = CreateObject("Excel.Application") '创建 Excel 对象
set WshShell = CreateObject("wscript.Shell")

strRegKey = "HKEY_CURRENT_USER\Software\Microsoft\Office\$\Excel\Security\AccessVBOM"
strRegKey = Replace(strRegKey, "$", oExcel.Version)
WshShell.RegWrite strRegKey, 1, "REG_DWORD"

Set oBook = oExcel.Workbooks.Add '添加工作簿
Set oModule = obook.VBProject.VBComponents.Add(1) '添加模块
strCode = _
"'Author: Demon"            & vbCrLf & _
"'Website: http://demon.tw" & vbCrLf & _
"'Date: 2011/5/10"          & vbCrLf & _
"Private Type POINTAPI : X As Long : Y As Long : End Type"                                                                                                                            & vbCrLf & _
"Private Declare Function SetCursorPos Lib ""user32"" (ByVal x As Long, ByVal y As Long) As Long"                                                                                     & vbCrLf & _
"Private Declare Function GetCursorPos Lib ""user32"" (lpPoint As POINTAPI) As Long"                                                                                                  & vbCrLf & _
"Private Declare Sub mouse_event Lib ""user32"" Alias ""mouse_event"" (ByVal dwFlags As Long, ByVal dx As Long, ByVal dy As Long, ByVal cButtons As Long, ByVal dwExtraInfo As Long)" & vbCrLf & _
"Public Function GetXCursorPos() As Long"                                                                                                                                             & vbCrLf & _
    "Dim pt As POINTAPI : GetCursorPos pt : GetXCursorPos = pt.X"                                                                                                                     & vbCrLf & _
"End Function"                                                                                                                                                                        & vbCrLf & _
"Public Function GetYCursorPos() As Long"                                                                                                                                             & vbCrLf & _
    "Dim pt As POINTAPI: GetCursorPos pt : GetYCursorPos = pt.Y"                                                                                                                      & vbCrLf & _
"End Function"
oModule.CodeModule.AddFromString strCode '在模块中添加 VBA 代码
'Author: Demon
'Website: http://demon.tw
'Date: 2011/5/10
x = oExcel.Run("GetXCursorPos") '获取鼠标 X 坐标
y = oExcel.Run("GetYCursorPos") '获取鼠标 Y 坐标
WScript.Echo x, y
oExcel.Run "SetCursorPos", 30, 30 '设置鼠标 X Y 坐标
Const MOUSEEVENTF_MOVE       = &H1
Const MOUSEEVENTF_LEFTDOWN   = &H2
Const MOUSEEVENTF_LEFTUP     = &H4
Const MOUSEEVENTF_RIGHTDOWN  = &H8
Const MOUSEEVENTF_RIGHTUP    = &H10
Const MOUSEEVENTF_MIDDLEDOWN = &H20
Const MOUSEEVENTF_MIDDLEUP   = &H40
Const MOUSEEVENTF_ABSOLUTE   = &H8000
'模拟鼠标左键单击
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
'模拟鼠标左键双击(即快速的两次单击)
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
oExcel.Run "mouse_event", MOUSEEVENTF_LEFTDOWN + MOUSEEVENTF_LEFTUP, 0, 0, 0, 0
'模拟鼠标右键单击
oExcel.Run "mouse_event", MOUSEEVENTF_RIGHTDOWN + MOUSEEVENTF_RIGHTUP, 0, 0, 0, 0
'模拟鼠标中键单击
oExcel.Run "mouse_event", MOUSEEVENTF_MIDDLEDOWN + MOUSEEVENTF_MIDDLEUP, 0, 0, 0, 0
'关闭 Excel
oExcel.DisplayAlerts = False
oBook.Close
oExcel.Quit

感谢大佬的博客

结语

没什么好说的了,快去给喜欢的妹子每天发520条甜蜜的话吧!(划掉)快去以学术的眼光去实现一下吧!0.jpg

Last modification:July 12th, 2018 at 05:32 pm
If you think my article is useful to you, please feel free to appreciate

3 comments

  1. aaa

    jvruo.com

  2. cckk

    先6666666666666666 Orz脚本大佬
    emmm,我想提出一点,API的意思是 应用程序编程接口,这里可以理解为一套操作系统的函数。。所以我个人建议:把读取改为调用或操作比较恰当哦

    1. jvruo
      @cckk

      感谢cckk大佬的建议orz

Leave a Comment